NAME¶

Mojo::Collection - Collection

SYNOPSIS¶

  # Manipulate collections
  use Mojo::Collection;
  my $collection = Mojo::Collection->new(qw(just works));
  unshift @$collection, 'it';
  $collection->map(sub { ucfirst })->each(sub {
    my ($word, $count) = @_;
    say "$count: $word";
  });
  # Use the alternative constructor
  use Mojo::Collection 'c';
  c(qw(a b c))->join('/')->url_escape->say;

DESCRIPTION¶

Mojo::Collection is a container for collections.

FUNCTIONS¶

Mojo::Collection implements the following functions.

"c"¶

  my $collection = c(1, 2, 3);

Construct a new Mojo::Collection object.

METHODS¶

Mojo::Collection implements the following methods.

"new"¶

  my $collection = Mojo::Collection->new(1, 2, 3);

Construct a new Mojo::Collection object.

"each"¶

  my @elements = $collection->each;
  $collection  = $collection->each(sub {...});

Evaluate closure for each element in collection.

  $collection->each(sub {
    my ($e, $count) = @_;
    say "$count: $e";
  });

"first"¶

  my $first = $collection->first;
  my $first = $collection->first(sub {...});

Evaluate closure for each element in collection and return the first one for which the closure returns true.

  my $five = $collection->first(sub { $_ == 5 });

"grep"¶

  my $new = $collection->grep(sub {...});

Evaluate closure for each element in collection and create a new collection with all elements for which the closure returned true.

  my $interesting = $collection->grep(sub { /mojo/i });

"join"¶

  my $stream = $collection->join("\n");

Turn collection into Mojo::ByteStream.

  $collection->join("\n")->say;

"map"¶

  my $new = $collection->map(sub {...});

Evaluate closure for each element in collection and create a new collection from the results.

  my $doubled = $collection->map(sub { $_ * 2 });

"reverse"¶

  my $new = $collection->reverse;

Create a new collection with all elements in reverse order.

"slice"¶

  my $new = $collection->slice(4 .. 7);

Create a new collection with all selected elements.

"shuffle"¶

  my $new = $collection->shuffle;

Create a new collection with all elements in random order.

"size"¶

  my $size = $collection->size;

Number of elements in collection.

"sort"¶

  my $new = $collection->sort;
  my $new = $collection->sort(sub {...});

Sort elements based on return value of closure and create a new collection from the results.

  my $insensitive = $collection->sort(sub { uc(shift) cmp uc(shift) });

SEE ALSO¶

Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.