Scroll to navigation

Mojo::Collection(3pm) User Contributed Perl Documentation Mojo::Collection(3pm)
 

NAME

Mojo::Collection - Collection

SYNOPSIS

  use Mojo::Collection;
  # Manipulate collection
  my $collection = Mojo::Collection->new(qw(just works));
  unshift @$collection, 'it';
  # Chain methods
  $collection->map(sub { ucfirst })->shuffle->each(sub {
    my ($word, $count) = @_;
    say "$count: $word";
  });
  # Stringify collection
  say $collection->join("\n");
  say "$collection";
  # Use the alternative constructor
  use Mojo::Collection 'c';
  c(qw(a b c))->join('/')->url_escape->say;

DESCRIPTION

Mojo::Collection is an array-based container for collections.
  # Access array directly to manipulate collection
  my $collection = Mojo::Collection->new(1 .. 25);
  $collection->[23] += 100;
  say for @$collection;

FUNCTIONS

Mojo::Collection implements the following functions, which can be imported individually.

c

  my $collection = c(1, 2, 3);
Construct a new array-based Mojo::Collection object.

METHODS

Mojo::Collection implements the following methods.

compact

  my $new = $collection->compact;
Create a new collection with all elements that are defined and not an empty string.

each

  my @elements = $collection->each;
  $collection  = $collection->each(sub {...});
Evaluate callback for each element in collection or return all elements as a list if none has been provided. The element will be the first argument passed to the callback and is also available as $_.
  # Make a numbered list
  $collection->each(sub {
    my ($e, $count) = @_;
    say "$count: $e";
  });

first

  my $first = $collection->first;
  my $first = $collection->first(qr/foo/);
  my $first = $collection->first(sub {...});
Evaluate regular expression or callback for each element in collection and return the first one that matched the regular expression, or for which the callback returned true. The element will be the first argument passed to the callback and is also available as $_.
  # Find first value that is greater than 5
  my $greater = $collection->first(sub { $_ > 5 });

flatten

  my $new = $collection->flatten;
Flatten nested collections/arrays recursively and create a new collection with all elements.

grep

  my $new = $collection->grep(qr/foo/);
  my $new = $collection->grep(sub {...});
Evaluate regular expression or callback for each element in collection and create a new collection with all elements that matched the regular expression, or for which the callback returned true. The element will be the first argument passed to the callback and is also available as $_.
  # Find all values that contain the word "mojo"
  my $interesting = $collection->grep(qr/mojo/i);

join

  my $stream = $collection->join;
  my $stream = $collection->join("\n");
Turn collection into Mojo::ByteStream.
  # Join all values with commas
  $collection->join(', ')->say;

last

  my $last = $collection->last;
Return the last element in collection.

map

  my $new = $collection->map(sub {...});
Evaluate callback for each element in collection and create a new collection from the results. The element will be the first argument passed to the callback and is also available as $_.
  # Append the word "mojo" to all values
  my $mojoified = $collection->map(sub { $_ . 'mojo' });

new

  my $collection = Mojo::Collection->new(1, 2, 3);
Construct a new array-based Mojo::Collection object.

pluck

  my $new = $collection->pluck($key);
  my $new = $collection->pluck($method);
  my $new = $collection->pluck($method, @args);
Extract hash reference value from, or call method on, each element in collection and create a new collection from the results.
  # Longer version
  my $new = $collection->map(sub { $_->{$key} });
  my $new = $collection->map(sub { $_->$method(@args) });

reduce

  my $result = $collection->reduce(sub {...});
  my $result = $collection->reduce(sub {...}, $initial);
Reduce elements in collection with callback, the first element will be used as initial value if none has been provided.
  # Calculate the sum of all values
  my $sum = $collection->reduce(sub { $a + $b });
  # Count how often each value occurs in collection
  my $hash = $collection->reduce(sub { $a->{$b}++; $a }, {});

reverse

  my $new = $collection->reverse;
Create a new collection with all elements in reverse order.

slice

  my $new = $collection->slice(4 .. 7);
Create a new collection with all selected elements.

shuffle

  my $new = $collection->shuffle;
Create a new collection with all elements in random order.

size

  my $size = $collection->size;
Number of elements in collection.

sort

  my $new = $collection->sort;
  my $new = $collection->sort(sub {...});
Sort elements based on return value of callback and create a new collection from the results.
  # Sort values case insensitive
  my $insensitive = $collection->sort(sub { uc($a) cmp uc($b) });

tap

  $collection = $collection->tap(sub {...});
Alias for "tap" in Mojo::Base.

uniq

  my $new = $collection->uniq;
Create a new collection without duplicate elements.

AUTOLOAD

In addition to the "METHODS" above, you can also call methods provided by all elements in the collection directly and create a new collection from the results, similar to "pluck".
  # "<h2>Test1</h2><h2>Test2</h2>"
  my $collection = Mojo::Collection->new(
    Mojo::DOM->new("<h1>1</h1>"), Mojo::DOM->new("<h1>2</h1>"));
  $collection->at('h1')->type('h2')->prepend_content('Test')->join;

OPERATORS

Mojo::Collection overloads the following operators.

bool

  my $bool = !!$collection;
Always true.

stringify

  my $str = "$collection";
Stringify elements in collection and "join" them with newlines.

SEE ALSO

Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.
2014-10-20 perl v5.20.1