NAME¶
Mojolicious::Routes - Always find your destination with routes
SYNOPSIS¶
use Mojolicious::Routes;
# New routes tree
my $r = Mojolicious::Routes->new;
# Normal route matching "/articles" with parameters "controller" and
# "action"
$r->route('/articles')->to(controller => 'article', action => 'list');
# Route with a placeholder matching everything but "/" and "."
$r->route('/:controller')->to(action => 'list');
# Route with a placeholder and regex constraint
$r->route('/articles/:id', id => qr/\d+/)
->to(controller => 'article', action => 'view');
# Route with an optional parameter "year"
$r->route('/archive/:year')
->to(controller => 'archive', action => 'list', year => undef);
# Nested route for two actions sharing the same "controller" parameter
my $books = $r->route('/books/:id')->to(controller => 'book');
$books->route('/edit')->to(action => 'edit');
$books->route('/delete')->to(action => 'delete');
# Bridges can be used to chain multiple routes
$r->bridge->to(controller => 'foo', action =>'auth')
->route('/blog')->to(action => 'list');
# Simplified Mojolicious::Lite style route generation is also possible
$r->get('/')->to(controller => 'blog', action => 'welcome');
my $blog = $r->under('/blog');
$blog->post('/list')->to('blog#list');
$blog->get(sub { shift->render(text => 'Go away!') });
DESCRIPTION¶
Mojolicious::Routes is the core of the Mojolicious web framework.
See Mojolicious::Guides::Routing for more.
ATTRIBUTES¶
Mojolicious::Routes inherits all attributes from Mojolicious::Routes::Route and
implements the following new ones.
"base_classes"¶
my $classes = $r->base_classes;
$r = $r->base_classes(['MyApp::Controller']);
Base classes used to identify controllers, defaults to Mojolicious::Controller
and Mojo.
"cache"¶
my $cache = $r->cache;
$r = $r->cache(Mojo::Cache->new);
Routing cache, defaults to a Mojo::Cache object.
# Disable caching
$r->cache(0);
"conditions"¶
my $conditions = $r->conditions;
$r = $r->conditions({foo => sub {...}});
Contains all available conditions.
"hidden"¶
my $hidden = $r->hidden;
$r = $r->hidden([qw(attr has new)]);
Controller methods and attributes that are hidden from routes, defaults to
"attr", "has" and "new".
"namespace"¶
my $namespace = $r->namespace;
$r = $r->namespace('Foo::Bar::Controller');
Namespace used by "dispatch" to search for controllers.
"shortcuts"¶
my $shortcuts = $r->shortcuts;
$r = $r->shortcuts({foo => sub {...}});
Contains all available shortcuts.
METHODS¶
Mojolicious::Routes inherits all methods from Mojolicious::Routes::Route and
implements the following ones.
"add_condition"¶
$r = $r->add_condition(foo => sub {...});
Add a new condition.
"add_shortcut"¶
$r = $r->add_shortcut(foo => sub {...});
Add a new shortcut.
"auto_render"¶
$r->auto_render(Mojolicious::Controller->new);
Automatic rendering.
"dispatch"¶
my $success = $r->dispatch(Mojolicious::Controller->new);
Match routes with Mojolicious::Routes::Match and dispatch.
"hide"¶
$r = $r->hide(qw(foo bar));
Hide controller methods and attributes from routes.
"route"¶
my $route = $r->route;
my $route = $r->route('/:action');
my $route = $r->route('/:action', action => qr/\w+/);
my $route = $r->route(format => 0);
Generate route matching all HTTP request methods.
SEE ALSO¶
Mojolicious, Mojolicious::Guides, <
http://mojolicio.us>.