NAME¶
Mojo::Base - Minimal base class for Mojo projects
SYNOPSIS¶
package Cat;
use Mojo::Base -base;
has name => 'Nyan';
has [qw(birds mice)] => 2;
package Tiger;
use Mojo::Base 'Cat';
has friend => sub { Cat->new };
has stripes => 42;
package main;
use Mojo::Base -strict;
my $mew = Cat->new(name => 'Longcat');
say $mew->mice;
say $mew->mice(3)->birds(4)->mice;
my $rawr = Tiger->new(stripes => 23, mice => 0);
say $rawr->tap(sub { $_->friend->name('Tacgnol') })->mice;
DESCRIPTION¶
Mojo::Base is a simple base class for Mojo projects.
# Automatically enables "strict", "warnings", "utf8" and Perl 5.10 features
use Mojo::Base -strict;
use Mojo::Base -base;
use Mojo::Base 'SomeBaseClass';
All three forms save a lot of typing.
# use Mojo::Base -strict;
use strict;
use warnings;
use utf8;
use feature ':5.10';
use IO::Handle ();
# use Mojo::Base -base;
use strict;
use warnings;
use utf8;
use feature ':5.10';
use IO::Handle ();
use Mojo::Base;
push @ISA, 'Mojo::Base';
sub has { Mojo::Base::attr(__PACKAGE__, @_) }
# use Mojo::Base 'SomeBaseClass';
use strict;
use warnings;
use utf8;
use feature ':5.10';
use IO::Handle ();
require SomeBaseClass;
push @ISA, 'SomeBaseClass';
use Mojo::Base;
sub has { Mojo::Base::attr(__PACKAGE__, @_) }
FUNCTIONS¶
Mojo::Base exports the following functions if imported with the
"-base" flag or a base class.
has¶
has 'name';
has [qw(name1 name2 name3)];
has name => 'foo';
has name => sub {...};
has [qw(name1 name2 name3)] => 'foo';
has [qw(name1 name2 name3)] => sub {...};
Create attributes for hash-based objects, just like the "attr" method.
METHODS¶
Mojo::Base implements the following methods.
new¶
my $object = BaseSubClass->new;
my $object = BaseSubClass->new(name => 'value');
my $object = BaseSubClass->new({name => 'value'});
This base class provides a basic constructor for hash-based objects. You can
pass it either a hash or a hash reference with attribute values.
attr¶
$object->attr('name');
BaseSubClass->attr('name');
BaseSubClass->attr([qw(name1 name2 name3)]);
BaseSubClass->attr(name => 'foo');
BaseSubClass->attr(name => sub {...});
BaseSubClass->attr([qw(name1 name2 name3)] => 'foo');
BaseSubClass->attr([qw(name1 name2 name3)] => sub {...});
Create attribute accessor for hash-based objects, an array reference can be used
to create more than one at a time. Pass an optional second argument to set a
default value, it should be a constant or a callback. The callback will be
excuted at accessor read time if there's no set value. Accessors can be
chained, that means they return their invocant when they are called with an
argument.
tap¶
$object = $object->tap(sub {...});
K combinator, tap into a method chain to perform operations on an object within
the chain. The object will be the first argument passed to the closure and is
also available via $_.
DEBUGGING¶
You can set the MOJO_BASE_DEBUG environment variable to get some advanced
diagnostics information printed to "STDERR".
MOJO_BASE_DEBUG=1
SEE ALSO¶
Mojolicious, Mojolicious::Guides, <
http://mojolicio.us>.