NAME¶

Mojo::Server::Daemon - Non-blocking I/O HTTP and WebSocket server

SYNOPSIS¶

  use Mojo::Server::Daemon;
  my $daemon = Mojo::Server::Daemon->new(listen => ['http://*:8080']);
  $daemon->unsubscribe('request');
  $daemon->on(request => sub {
    my ($daemon, $tx) = @_;
    # Request
    my $method = $tx->req->method;
    my $path   = $tx->req->url->path;
    # Response
    $tx->res->code(200);
    $tx->res->headers->content_type('text/plain');
    $tx->res->body("$method request for $path!");
    # Resume transaction
    $tx->resume;
  });
  $daemon->run;

DESCRIPTION¶

Mojo::Server::Daemon is a full featured, highly portable non-blocking I/O HTTP and WebSocket server, with IPv6, TLS, Comet (long polling), keep-alive and multiple event loop support. For better scalability (epoll, kqueue) and to provide IPv6, SOCKS5 as well as TLS support, the optional modules EV (4.0+), IO::Socket::IP (0.20+), IO::Socket::Socks (0.64+) and IO::Socket::SSL (1.84+) will be used automatically if they are installed. Individual features can also be disabled with the "MOJO_NO_IPV6", "MOJO_NO_SOCKS" and "MOJO_NO_TLS" environment variables. See "DEPLOYMENT" in Mojolicious::Guides::Cookbook for more.

EVENTS¶

Mojo::Server::Daemon inherits all events from Mojo::Server.

ATTRIBUTES¶

Mojo::Server::Daemon inherits all attributes from Mojo::Server and implements the following new ones.

acceptors¶

  my $acceptors = $daemon->acceptors;
  $daemon       = $daemon->acceptors([]);

Active acceptors.

backlog¶

  my $backlog = $daemon->backlog;
  $daemon     = $daemon->backlog(128);

Listen backlog size, defaults to "SOMAXCONN".

inactivity_timeout¶

  my $timeout = $daemon->inactivity_timeout;
  $daemon     = $daemon->inactivity_timeout(5);

Maximum amount of time in seconds a connection can be inactive before getting closed, defaults to the value of the "MOJO_INACTIVITY_TIMEOUT" environment variable or 15. Setting the value to 0 will allow connections to be inactive indefinitely.

ioloop¶

  my $loop = $daemon->ioloop;
  $daemon  = $daemon->ioloop(Mojo::IOLoop->new);

Event loop object to use for I/O operations, defaults to the global Mojo::IOLoop singleton.

listen¶

  my $listen = $daemon->listen;
  $daemon    = $daemon->listen(['https://localhost:3000']);

List of one or more locations to listen on, defaults to the value of the "MOJO_LISTEN" environment variable or "http://*:3000".

  # Listen on all IPv4 interfaces
  $daemon->listen(['http://*:3000']);
  # Listen on all IPv4 and IPv6 interfaces
  $daemon->listen(['http://[::]:3000']);
  # Listen on IPv6 interface
  $daemon->listen(['http://[::1]:4000']);
  # Listen on IPv4 and IPv6 interfaces
  $daemon->listen(['http://127.0.0.1:3000', 'http://[::1]:3000']);
  # Allow multiple servers to use the same port (SO_REUSEPORT)
  $daemon->listen(['http://*:8080?reuse=1']);
  # Listen on two ports with HTTP and HTTPS at the same time
  $daemon->listen([qw(http://*:3000 https://*:4000)]);
  # Use a custom certificate and key
  $daemon->listen(['https://*:3000?cert=/x/server.crt&key=/y/server.key']);
  # Or even a custom certificate authority
  $daemon->listen(
    ['https://*:3000?cert=/x/server.crt&key=/y/server.key&ca=/z/ca.crt']);

These parameters are currently available:

ca

  ca=/etc/tls/ca.crt
    

Path to TLS certificate authority file.

cert

  cert=/etc/tls/server.crt
    

Path to the TLS cert file, defaults to a built-in test certificate.

ciphers

  ciphers=AES128-GCM-SHA256:RC4:HIGH:!MD5:!aNULL:!EDH
    

Cipher specification string.

key

  key=/etc/tls/server.key
    

Path to the TLS key file, defaults to a built-in test key.

reuse

  reuse=1
    

Allow multiple servers to use the same port with the "SO_REUSEPORT" socket option.

verify

  verify=0x00
    

TLS verification mode, defaults to 0x03.

max_clients¶

  my $max = $daemon->max_clients;
  $daemon = $daemon->max_clients(1000);

Maximum number of concurrent client connections, passed along to "max_connections" in Mojo::IOLoop.

max_requests¶

  my $max = $daemon->max_requests;
  $daemon = $daemon->max_requests(100);

Maximum number of keep-alive requests per connection, defaults to 25.

silent¶

  my $bool = $daemon->silent;
  $daemon  = $daemon->silent($bool);

Disable console messages.

METHODS¶

Mojo::Server::Daemon inherits all methods from Mojo::Server and implements the following new ones.

run¶

  $daemon->run;

Run server.

start¶

  $daemon = $daemon->start;

Start accepting connections.

  # Listen on random port
  my $id   = $daemon->listen(['http://127.0.0.1'])->start->acceptors->[0];
  my $port = $daemon->ioloop->acceptor($id)->handle->sockport;

stop¶

  $daemon = $daemon->stop;

Stop accepting connections.

DEBUGGING¶

You can set the "MOJO_DAEMON_DEBUG" environment variable to get some advanced diagnostics information printed to "STDERR".

  MOJO_DAEMON_DEBUG=1

SEE ALSO¶

Mojolicious, Mojolicious::Guides, <http://mojolicio.us>.