Scroll to navigation

STAPEX(3stap) STAPEX(3stap)

JMÉNO

stapex - příklady

ZÁKLADY SKRIPTOVACÍHO JAZYKA

Následující příklady demonstrují základy syntaxe a řídicích struktur skriptovacího jazyka systemtapu. 

global odds, evens
probe begin {
  # "no" and "ne" are local integers
  for (i=0; i<10; i++) {
    if (i % 2) odds [no++] = i
    else evens [ne++] = i
  }
  delete odds[2]
  delete evens[3]
  exit ()
}
probe end {
  foreach (x+ in odds) {
    printf ("odds[%d] = %d\n", x, odds[x])
  }
  foreach (x in evens-) {
    printf ("evens[%d] = %d\n", x, evens[x])
  }
}

Výstupem výše uvedeného skriptu bude:

odds[1] = 1
odds[3] = 5
odds[4] = 7
odds[5] = 9
evens[5] = 8
evens[4] = 6
evens[2] = 2
evens[1] = 0

Poznamenejme, že datové typy všech proměnných jsou automaticky odvozené, a že všechny globální proměnné jsou automaticky inicializovány.

Následující skript vypíše prvočísla mezi 0 a 49.

function isprime (x) {
  if (x < 2) return 0
  for (i=2; i<x; i++) {
    if (x % i == 0) return 0
    if (i * i > x) break
  }
  return 1
}
probe begin {
  for (i=0; i<50; i++)
    if (isprime (i)) printf("%d\n", i)
  exit()
}

Tento skript je ukázkou použití rekurzivních funkcí.

function fibonacci(i) {
  if (i < 1) error ("bad number")
  if (i == 1) return 1
  if (i == 2) return 2
  return fibonacci (i-1) + fibonacci (i-2)
}
probe begin {
  printf ("11th fibonacci number: %d\n", fibonacci (11))
  exit ()
}

Při pokusu o generování větších čísel bychom narazili na limity MAXACTION, nebo MAXNESTING a výsledkem by byla chyba.

SONDOVÁNÍ

Pro sledování vstupu do funkce a výstupu z ní použijte následující pár sond: 

probe kernel.function("sys_mkdir") { println ("enter") }
probe kernel.function("sys_mkdir").return { println ("exit") }

Pro vypsání jaderných funkcí do kterých lze vložit sondu použijte režim výpisu -l:

% stap -l 'kernel.function("*")'

Pro výpis jaderných funkcí a v nich přístupných lokálních proměnných použijte režim výpisu -L:

% stap -L 'kernel.function("*")'

VÍCE PŘÍKLADŮ

Adresář s příklady je zmíněn v manuálové stránce stappaths (7), případně online na adrese: http://sourceware.org/systemtap/examples/

VIZ TÉŽ

stap(1)
stapprobes(3stap)
stappaths(7)